Namespace Prefixes | Inference Rules

What DBs target mammals? (哺乳類を対象にしたDBを知りたい)

DEFINE input:inference "subClassOf_NCBITaxon"
PREFIX dbc: <http://integbio.jp/dbcatalog/meta#>
SELECT DISTINCT ?db_name ?db_id ?organism
WHERE {
  ?taxon rdfs:label "Mammalia"^^xsd:string .
  ?sub rdfs:subClassOf ?taxon .
  ?db_id dbc:dbcat_taxonomy_id ?sub .
  ?db_id dbc:dbcat_db_name ?db_name .
  ?db_id dbc:dbcat_organism ?organism .
}
ORDER BY ?db_name

What taxa cover organisms containing alpha-Thujene? (α-ツジェンを生体内に含む生物の分類群は?)

DEFINE input:inference "subClassOf_NCBITaxon"
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX kc: <http://togodb.biosciencedbc.jp/ontology/knapsack_core#>
SELECT (STR(?label) AS ?name) ?total_super
{
  {
    SELECT ?super (COUNT(?super) AS ?total_super) WHERE {
      ?knapsackcore kc:metabolite "alpha-Thujene" .
      ?knapsackcore kc:organism_uri ?organism .
      ?organism rdfs:subClassOf ?super .
    }
    GROUP BY ?super
  }
  ?super rdfs:label ?label .
}
ORDER BY DESC(?total_super) ?label

What plants contain compounds that cause hypertrophy in rat livers? (ラットを肝細胞肥大させた化合物を含む植物は?)

PREFIX otp: <http://togodb.biosciencedbc.jp/ontology/open_tggates_pathology#>
PREFIX otm: <http://togodb.biosciencedbc.jp/ontology/open_tggates_main#>
PREFIX kc: <http://togodb.biosciencedbc.jp/ontology/knapsack_core#>
SELECT DISTINCT ?organism ?compound_name ?chebi
WHERE {
  ?tggatespatho otp:find_type "Hypertrophy" .
  ?tggatespatho otp:compound_name ?compound_name .
  ?tggatesmain otm:compound_name ?compound_name .
  ?tggatesmain otm:chebi ?chebi .
  ?knapsackcore kc:chebi ?chebi .
  ?knapsackcore kc:organism ?organism
}
ORDER BY ?organism

List up gene pairs on the photosynthesis pathway whose mutants show similar fluorescence time-course in Synechocystis sp. PCC 6803. (Synechocystis sp. PCC 6803 の Photosynthesis のパスウェイ上の遺伝子について,蛍光時系列が似ているもののリストが欲しい)

PREFIX fl: <http://togodb.biosciencedbc.jp/ontology/fluorome_sim#>
SELECT ?simid ?orf1 ?orf2 ?product1 ?product2 ?dist_h ?dist_l
WHERE {
   <http://www.kegg.jp/entry/syn00195> <http://www.genome.jp/linkdb/reverse> ?gene1 .
   BIND( IRI(CONCAT("http://identifiers.org/kegg.genes/syn:", SUBSTR(STR(?gene1), 30))) AS ?orf1 )
   ?simid fl:box1_orf ?orf1 .
   ?simid fl:box2_orf ?orf2 .
   ?simid fl:box1_product ?product1 .
   ?simid fl:box2_product ?product2 .
   OPTIONAL{ ?simid fl:distance_a_high ?dist_h . }
   ?simid fl:distance_a_low ?dist_l .
   BIND( IRI(CONCAT("http://www.kegg.jp/entry/syn:", SUBSTR(STR(?orf2), 39))) AS ?gene2 )
   FILTER ( ?orf1 != ?orf2 && ?dist_l < 0.2 )
   <http://www.kegg.jp/entry/syn00195> <http://www.genome.jp/linkdb/reverse> ?gene2 .
}

What proteins are targeted by compounds from Vigna unguiculata? (ササゲに含まれる化合物のターゲットタンパク質を知りたい)

PREFIX kc: <http://togodb.biosciencedbc.jp/ontology/knapsack_core#>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX chbl: <http://rdf.ebi.ac.uk/terms/chembl#>
SELECT DISTINCT ?compound_name ?target_name ?target
WHERE {
  ?kc_id kc:organism "Vigna unguiculata".
  ?kc_id kc:inchi ?inchi .
  ?kc_id kc:metabolite ?compound_name .

  SERVICE <https://www.ebi.ac.uk/rdf/services/chembl/sparql> {
    ?molecule sio:SIO_000008 ?attribute .
    FILTER regex(?attribute, "standard_inchi$") .
    ?attribute sio:SIO_000300 ?inchi .
    ?activity chbl:hasMolecule ?molecule .
    ?activity chbl:hasAssay ?assay .
    ?assay chbl:hasTarget ?target .
    ?target rdfs:label ?target_name .
  }
}
ORDER BY ?compound_name ?target_name ?target

Copyright © 2013 National Bioscience Database Center. All Rights Reserved.